arg_max()(집계 함수)

적용 대상: ✅Microsoft Fabric

테이블에서 지정된 식을 최대화하는 행을 찾습니다. 입력 테이블 또는 지정된 열의 모든 열을 반환합니다.

사용되지 않는 별칭: argmax()

구문

arg_max ( ExprToMaximize,* | ExprToReturn [, ...])

구문 규칙에 대해 자세히 알아봅니다.

매개 변수

반품

ExprToMaximize지정된 식과 ExprToReturn지정된 열 값을 최대화하는 테이블의 행을 반환합니다.

예제

일반 예제

다음 예제에서는 각 상태에서 Storm 이벤트의 최대 위도를 찾습니다.

StormEvents 
| summarize arg_max(BeginLat, BeginLocation) by State

출력

결과 테이블에는 처음 10개 행만 표시됩니다.

다음 예제에서는 모든 열을 보여 주는 각 상태에서 직접 사망 이벤트가 마지막으로 발생한 시간을 찾습니다.

쿼리는 먼저 이벤트를 필터링하여 최소 한 번의 직접 사망이 발생한 이벤트만 포함합니다. 그런 다음 쿼리는 가장 최근 StartTime사용하여 전체 행을 반환합니다.

StormEvents
| where DeathsDirect > 0
| summarize arg_max(StartTime, *) by State

출력

결과 테이블에는 처음 10개의 행과 처음 세 개의 열만 표시됩니다.

다음 예제에서는 null 처리를 보여 줍니다.

datatable(Fruit: string, Color: string, Version: int) [
    "Apple", "Red", 1,
    "Apple", "Green", int(null),
    "Banana", "Yellow", int(null),
    "Banana", "Green", int(null),
    "Pear", "Brown", 1,
    "Pear", "Green", 2,
]
| summarize arg_max(Version, *) by Fruit

출력

arg_max() 및 max()를 비교하는 예제

arg_max() 함수는 max() 함수다릅니다. arg_max() 함수를 사용하면 최대값과 함께 다른 열을 반환할 수 있으며 max() 최대값 자체만 반환합니다.

다음 예제에서는 arg_max()를 사용하여 각 상태에서 직접 사망 이벤트가 마지막으로 발생한 시간을 찾아 모든 열을 표시합니다. 쿼리는 먼저 이벤트를 필터링하여 직접 사망이 하나 이상 발생한 이벤트만 포함합니다. 그런 다음 쿼리는 가장 최근(최대) StartTime을 사용하여 전체 행을 반환합니다.

StormEvents
| where DeathsDirect > 0
| summarize arg_max(StartTime, *)

결과 테이블은 지정된 식에서 가장 높은 값을 포함하는 행의 모든 열을 반환합니다.

다음 예제에서는 max() 함수를 사용하여 각 상태에서 직접 사망 이벤트가 발생한 마지막 시간을 찾지만 StartTime의 최대값만 반환합니다.

StormEvents
| where DeathsDirect > 0
| summarize max(StartTime)

결과 테이블은 이 레코드에 대한 다른 열을 반환하지 않고 StartTime의 최대값을 반환합니다.

관련 콘텐츠

• 집계 함수 형식 한 눈에 보기
• arg_min 함수
• 최대 함수
• 평균 함수
• 백분위수 함수