练习 - 为存储帐户和数据库设定种子

14 分钟

你已对管道进行更新以生成网站的应用程序，并将其部署到 Bicep 文件中定义的 Azure 应用服务应用。但是冒烟测试阶段失败，因为数据库尚未正常工作。在本单元中，你将部署一个新的 Azure SQL 逻辑服务器和数据库，并将管道配置为生成和部署数据库的架构。还可以更新管道，为测试环境添加一些示例产品数据，以便团队可以试用网站。

在此过程中，将执行以下任务：

将 Blob 容器添加到 Azure 存储帐户。
添加 Azure SQL 逻辑服务器和数据库。
更新生成阶段，将数据库项目生成到 DACPAC 文件中。
将新变量添加到 Azure SQL 逻辑服务器和数据库的变量组中。
更新部署阶段，以使用新变量作为参数值。
添加新的管道步骤以部署 DACPAC 文件。
运行管道并查看网站。

添加存储容器

Bicep 文件已经定义了一个存储帐户，但没有定义 Blob 容器。将在此处将 Blob 容器添加到 Bicep 文件。还需使用应用程序的配置设置为应用程序提供存储帐户和 Blob 容器的名称。这样，应用便知道要访问哪个存储帐户。

在 Visual Studio Code 中，打开 deploy 文件夹中的 main.bicep 文件。
在定义资源名称（靠近第 27 行）的变量下面，为 Blob 存储容器的名称添加新的变量定义：
```
var storageAccountImagesBlobContainerName = 'toyimages'
```

更新 storageAccount 资源以定义 Blob 容器：

resource storageAccount 'Microsoft.Storage/storageAccounts@2022-09-01' = {
  name: storageAccountName
  ___location: ___location
  kind: 'StorageV2'
  sku: environmentConfigurationMap[environmentType].storageAccount.sku

  resource blobService 'blobServices' = {
    name: 'default'

    resource storageAccountImagesBlobContainer 'containers' = {
      name: storageAccountImagesBlobContainerName

      properties: {
        publicAccess: 'Blob'
      }
    }
  }
}

更新应用 appSettings 的属性，为存储帐户名称、Blob 终结点和 Blob 容器名称添加三个新应用程序设置：

resource appServiceApp 'Microsoft.Web/sites@2022-03-01' = {
  name: appServiceAppName
  ___location: ___location
  properties: {
    serverFarmId: appServicePlan.id
    httpsOnly: true
    siteConfig: {
      appSettings: [
        {
          name: 'APPINSIGHTS_INSTRUMENTATIONKEY'
          value: applicationInsights.properties.InstrumentationKey
        }
        {
          name: 'APPLICATIONINSIGHTS_CONNECTION_STRING'
          value: applicationInsights.properties.ConnectionString
        }
        {
          name: 'ReviewApiUrl'
          value: reviewApiUrl
        }
        {
          name: 'ReviewApiKey'
          value: reviewApiKey
        }
        {
          name: 'StorageAccountName'
          value: storageAccount.name
        }
        {
          name: 'StorageAccountBlobEndpoint'
          value: storageAccount.properties.primaryEndpoints.blob
        }
        {
          name: 'StorageAccountImagesContainerName'
          value: storageAccount::blobService::storageAccountImagesBlobContainer.name
        }
      ]
    }
  }
}

在文件末尾，添加新输出以公开存储帐户和 Blob 容器的名称：

output storageAccountName string = storageAccount.name
output storageAccountImagesBlobContainerName string = storageAccount::blobService::storageAccountImagesBlobContainer.name

保存对该文件所做的更改。
将更改提交到 Git 存储库，但不要对其进行推送。在 Visual Studio Code 终端中，运行以下命令：
```
git add .
git commit -m "Add storage container"
```

添加 Azure SQL 逻辑服务器和数据库

Bicep 文件当前未部署 Azure SQL 逻辑服务器或数据库。在本部分中，你将这些资源添加到 Bicep 文件。

在 main.bicep 文件中，在参数下方 reviewApiKey 添加两个新参数：

@description('The administrator login username for the SQL server.')
param sqlServerAdministratorLogin string

@secure()
@description('The administrator login password for the SQL server.')
param sqlServerAdministratorLoginPassword string

在定义资源名称的变量下方，添加新变量以定义 Azure SQL 逻辑服务器和数据库的名称：
```
var sqlServerName = 'toy-website-${resourceNameSuffix}'
var sqlDatabaseName = 'Toys'
```
在刚添加的变量下面，定义一个新变量，该变量会创建应用程序用于访问数据库的连接字符串：
```
// Define the connection string to access Azure SQL.
var sqlDatabaseConnectionString = 'Server=tcp:${sqlServer.properties.fullyQualifiedDomainName},1433;Initial Catalog=${sqlDatabase.name};Persist Security Info=False;User ID=${sqlServerAdministratorLogin};Password=${sqlServerAdministratorLoginPassword};MultipleActiveResultSets=False;Encrypt=True;TrustServerCertificate=False;Connection Timeout=30;'
```
注释

为简单起见，应用程序将使用管理员登录名和密码来访问数据库。但对于生产解决方案而言，这并非是很好的做法。最好使用应用服务托管标识来访问数据库，并向托管标识授予应用程序所需的最小权限。我们链接到“摘要”页上的详细信息。

在文件末尾附近，在输出上方添加 Azure SQL 逻辑服务器和数据库资源：

resource sqlServer 'Microsoft.Sql/servers@2022-05-01-preview' = {
  name: sqlServerName
  ___location: ___location
  properties: {
    administratorLogin: sqlServerAdministratorLogin
    administratorLoginPassword: sqlServerAdministratorLoginPassword
  }
}

resource sqlServerFirewallRule 'Microsoft.Sql/servers/firewallRules@2022-05-01-preview' = {
  parent: sqlServer
  name: 'AllowAllWindowsAzureIps'
  properties: {
    endIpAddress: '0.0.0.0'
    startIpAddress: '0.0.0.0'
  }
}

resource sqlDatabase 'Microsoft.Sql/servers/databases@2022-05-01-preview' = {
  parent: sqlServer
  name: sqlDatabaseName
  ___location: ___location
  sku: environmentConfigurationMap[environmentType].sqlDatabase.sku
}

将 environmentConfigurationMap 变量更新为定义每个环境的数据库使用的 sku 值：

var environmentConfigurationMap = {
  Production: {
    appServicePlan: {
      sku: {
        name: 'S1'
        capacity: 1
      }
    }
    storageAccount: {
      sku: {
        name: 'Standard_LRS'
      }
    }
    sqlDatabase: {
      sku: {
        name: 'Standard'
        tier: 'Standard'
      }
    }
  }
  Test: {
    appServicePlan: {
      sku: {
        name: 'F1'
      }
    }
    storageAccount: {
      sku: {
        name: 'Standard_GRS'
      }
    }
    sqlDatabase: {
      sku: {
        name: 'Standard'
        tier: 'Standard'
      }
    }
  }
}

在应用服务应用中为数据库连接字符串添加额外的应用设置：

resource appServiceApp 'Microsoft.Web/sites@2022-03-01' = {
  name: appServiceAppName
  ___location: ___location
  properties: {
    serverFarmId: appServicePlan.id
    httpsOnly: true
    siteConfig: {
      appSettings: [
        {
          name: 'APPINSIGHTS_INSTRUMENTATIONKEY'
          value: applicationInsights.properties.InstrumentationKey
        }
        {
          name: 'APPLICATIONINSIGHTS_CONNECTION_STRING'
          value: applicationInsights.properties.ConnectionString
        }
        {
          name: 'ReviewApiUrl'
          value: reviewApiUrl
        }
        {
          name: 'ReviewApiKey'
          value: reviewApiKey
        }
        {
          name: 'StorageAccountName'
          value: storageAccount.name
        }
        {
          name: 'StorageAccountBlobEndpoint'
          value: storageAccount.properties.primaryEndpoints.blob
        }
        {
          name: 'StorageAccountImagesContainerName'
          value: storageAccount::blobService::storageAccountImagesBlobContainer.name
        }
        {
          name: 'SqlDatabaseConnectionString'
          value: sqlDatabaseConnectionString
        }
      ]
    }
  }
}

在文件底部，添加输出以公开 Azure SQL 逻辑服务器的主机名和数据库名称：

output appServiceAppName string = appServiceApp.name
output appServiceAppHostName string = appServiceApp.properties.defaultHostName
output storageAccountName string = storageAccount.name
output storageAccountImagesBlobContainerName string = storageAccount::blobService::storageAccountImagesBlobContainer.name
output sqlServerFullyQualifiedDomainName string = sqlServer.properties.fullyQualifiedDomainName
output sqlDatabaseName string = sqlDatabase.name

保存对该文件所做的更改。

为数据库项目添加新的生成步骤

网站开发人员准备了一个 Visual Studio 数据库项目，用于部署和配置网站数据库表。在这里，你将更新管道“生成”阶段，以将数据库项目生成到 DACPAC 文件中，并将其发布为管道工件。

在 deploy/pipeline-templates 文件夹中打开build.yml文件。

若要生成 Visual Studio 数据库项目，请将生成的 DACPAC 文件复制到暂存文件夹，并将其发布为管道工件，然后添加以下步骤：

jobs:
- job: Build
  displayName: Build application and database
  pool:
    vmImage: windows-latest

  steps:

  # Build, copy, and publish the website.
  - task: DotNetCoreCLI@2
    displayName: Build publishable website
    inputs:
      command: 'publish'
      publishWebProjects: true

  - task: CopyFiles@2
    displayName: Copy publishable website
    inputs:
      sourceFolder: '$(Build.SourcesDirectory)/src/ToyCompany/ToyCompany.Website/bin'
      contents: '**/publish.zip'
      targetFolder: '$(Build.ArtifactStagingDirectory)/website'
      flattenFolders: true

  - task: PublishBuildArtifacts@1
    displayName: Publish website as pipeline artifact
    inputs:
      pathToPublish: '$(Build.ArtifactStagingDirectory)/website'
      artifactName: 'website'

  # Build, copy, and publish the DACPAC file.
  - task: VSBuild@1
    displayName: Build Visual Studio solution
    inputs:
      solution: '$(Build.SourcesDirectory)/src/ToyCompany/ToyCompany.Database/ToyCompany.Database.sqlproj'

  - task: CopyFiles@2
    displayName: Copy DACPAC
    inputs:
      sourceFolder: '$(Build.SourcesDirectory)/src/ToyCompany/ToyCompany.Database/bin'
      contents: '**/*.dacpac'
      targetFolder: '$(Build.ArtifactStagingDirectory)/database'
      flattenFolders: true

  - task: PublishBuildArtifacts@1
    displayName: Publish DACPAC as pipeline artifact
    inputs:
      pathToPublish: '$(Build.ArtifactStagingDirectory)/database'
      artifactName: 'database'

保存对该文件所做的更改。

将值添加到变量组

在浏览器中，转到“管道”“库”。
选择 ToyWebsiteProduction 变量组。
将以下变量添加到变量组：

名称价值

SqlServerAdministratorLogin ToyCompanyAdmin

SqlServerAdministratorLoginPassword SecurePassword！111
选择 SqlServerAdministratorLoginPassword 变量旁边的挂锁图标。此功能告知 Azure Pipelines 安全地处理变量的值。
保存变量组。
重复此过程，将以下变量添加到 ToyWebsiteTest 变量组：

名称价值

SqlServerAdministratorLogin TestToyCompanyAdmin

SqlServerAdministratorLoginPassword SecurePassword！999

请记住选择 SqlServerAdministratorLoginPassword 变量旁边的挂锁图标并保存变量组。

名称	价值
SqlServerAdministratorLogin	ToyCompanyAdmin
SqlServerAdministratorLoginPassword	SecurePassword！111

名称	价值
SqlServerAdministratorLogin	TestToyCompanyAdmin
SqlServerAdministratorLoginPassword	SecurePassword！999

向“验证”和“预览”阶段添加参数值

Bicep 文件现在具有两个新的必需参数：sqlServerAdministratorLogin 和 sqlServerAdministratorLoginPassword。在这里，你将从变量组中传播这些参数值，用于 “验证” 和 “预览” 阶段。

在 Visual Studio Code 中，打开 deploy/pipeline-templates 文件夹中的deploy.yml文件。

通过添加新参数更新验证阶段的 RunPreflightValidation 步骤。

- task: AzureResourceManagerTemplateDeployment@3
  name: RunPreflightValidation
  displayName: Run preflight validation
  inputs:
    connectedServiceName: ToyWebsite${{parameters.environmentType}}
    ___location: ${{parameters.deploymentDefaultLocation}}
    deploymentMode: Validation
    resourceGroupName: $(ResourceGroupName)
    csmFile: deploy/main.bicep
    overrideParameters: >
      -environmentType $(EnvironmentType)
      -reviewApiUrl $(ReviewApiUrl)
      -reviewApiKey $(ReviewApiKey)
      -sqlServerAdministratorLogin $(SqlServerAdministratorLogin)
      -sqlServerAdministratorLoginPassword $(SqlServerAdministratorLoginPassword)

通过添加新参数更新预览阶段的 RunWhatIf 步骤。

inlineScript: |
  az deployment group what-if \
    --resource-group $(ResourceGroupName) \
    --template-file deploy/main.bicep \
    --parameters environmentType=$(EnvironmentType) \
                 reviewApiUrl=$(ReviewApiUrl) \
                 reviewApiKey=$(ReviewApiKey) \
                 sqlServerAdministratorLogin=$(SqlServerAdministratorLogin) \
                 sqlServerAdministratorLoginPassword=$(SqlServerAdministratorLoginPassword)

重要

请务必在设置reviewApiKey参数值的行末尾以及后续行中添加反斜杠字符（\）。该 \ 字符指示有其他行属于同一 Azure CLI 命令。

将参数值添加到部署阶段

通过添加新参数更新部署阶段的 DeployBicepFile 步骤：

- task: AzureResourceManagerTemplateDeployment@3
  name: DeployBicepFile
  displayName: Deploy Bicep file
  inputs:
    connectedServiceName: ToyWebsite${{parameters.environmentType}}
    deploymentName: $(Build.BuildNumber)
    ___location: ${{parameters.deploymentDefaultLocation}}
    resourceGroupName: $(ResourceGroupName)
    csmFile: deploy/main.bicep
    overrideParameters: >
      -environmentType $(EnvironmentType)
      -reviewApiUrl $(ReviewApiUrl)
      -reviewApiKey $(ReviewApiKey)
      -sqlServerAdministratorLogin $(SqlServerAdministratorLogin)
      -sqlServerAdministratorLoginPassword $(SqlServerAdministratorLoginPassword)
    deploymentOutputs: deploymentOutputs

创建包含最近为存储帐户和 Azure SQL 资源添加的 Bicep 输出值的管道变量：

- bash: |
    echo "##vso[task.setvariable variable=appServiceAppName]$(echo $DEPLOYMENT_OUTPUTS | jq -r '.appServiceAppName.value')"
    echo "##vso[task.setvariable variable=appServiceAppHostName;isOutput=true]$(echo $DEPLOYMENT_OUTPUTS | jq -r '.appServiceAppHostName.value')"
    echo "##vso[task.setvariable variable=storageAccountName]$(echo $DEPLOYMENT_OUTPUTS | jq -r '.storageAccountName.value')"
    echo "##vso[task.setvariable variable=storageAccountImagesBlobContainerName]$(echo $DEPLOYMENT_OUTPUTS | jq -r '.storageAccountImagesBlobContainerName.value')"
    echo "##vso[task.setvariable variable=sqlServerFullyQualifiedDomainName]$(echo $DEPLOYMENT_OUTPUTS | jq -r '.sqlServerFullyQualifiedDomainName.value')"
    echo "##vso[task.setvariable variable=sqlDatabaseName]$(echo $DEPLOYMENT_OUTPUTS | jq -r '.sqlDatabaseName.value')"
  name: SaveDeploymentOutputs
  displayName: Save deployment outputs into variables
  env:
    DEPLOYMENT_OUTPUTS: $(deploymentOutputs)

添加数据库部署步骤

在本部分中，将定义部署网站数据库组件所需的步骤。首先，添加一个步骤来部署管道先前生成的 DACPAC 文件。然后，将示例数据添加到数据库和存储帐户，但仅适用于非生产性环境。

在部署阶段的 DeployWebsiteApp 步骤下方，添加一个新步骤来部署 DACPAC 文件：

- task: SqlAzureDacpacDeployment@1
  name: DeploySqlDatabaseDacpac
  displayName: Deploy DACPAC to database
  inputs:
    ConnectedServiceNameARM: ToyWebsite${{parameters.environmentType}}
    authenticationType: 'server'
    serverName: $(sqlServerFullyQualifiedDomainName)
    databaseName: $(sqlDatabaseName)
    sqlUsername: $(SqlServerAdministratorLogin)
    sqlPassword: $(SqlServerAdministratorLoginPassword)
    deployType: 'DacpacTask'
    deploymentAction: 'Publish'
    dacpacFile: '$(Pipeline.Workspace)/database/ToyCompany.Database.dacpac'

在刚刚添加的步骤下面，定义一个步骤，以使用示例数据为数据库设定种子。

- ${{ if ne(parameters.environmentType, 'Production') }}:
  - task: SqlAzureDacpacDeployment@1
    name: AddTestDataToDatabase
    displayName: Add test data to database
    inputs:
      ConnectedServiceNameARM: ToyWebsite${{parameters.environmentType}}
      authenticationType: 'server'
      serverName: $(sqlServerFullyQualifiedDomainName)
      databaseName: $(sqlDatabaseName)
      sqlUsername: $(SqlServerAdministratorLogin)
      sqlPassword: $(SqlServerAdministratorLoginPassword)
      deployType: 'sqlTask'
      sqlFile: 'deploy/sample-data/Toys.sql'

请注意，此步骤应用了一个条件，以便它仅针对非生产环境运行。

在您刚刚添加的步骤下面，并且仍在条件范围之内，添加一个步骤，使用 Azure CLI 将一些示例玩具图像上传到 Blob 容器。

- task: AzureCLI@2
  name: UploadSampleImages
  displayName: Upload sample images
  inputs:
    azureSubscription: ToyWebsite${{parameters.environmentType}}
    scriptType: 'bash'
    scriptLocation: 'inlineScript'
    inlineScript: |
      az storage blob upload-batch \
        --account-name $(storageAccountName) \
        --destination $(storageAccountImagesBlobContainerName) \
        --source 'deploy/sample-data/toyimages'

验证文件并提交更改

验证 main.bicep 文件是否如下所示：

@description('The ___location into which your Azure resources should be deployed.')
param ___location string = resourceGroup().___location

@description('Select the type of environment you want to provision. Allowed values are Production and Test.')
@allowed([
  'Production'
  'Test'
])
param environmentType string

@description('A unique suffix to add to resource names that need to be globally unique.')
@maxLength(13)
param resourceNameSuffix string = uniqueString(resourceGroup().id)

@description('The URL to the product review API.')
param reviewApiUrl string

@secure()
@description('The API key to use when accessing the product review API.')
param reviewApiKey string

@description('The administrator login username for the SQL server.')
param sqlServerAdministratorLogin string

@secure()
@description('The administrator login password for the SQL server.')
param sqlServerAdministratorLoginPassword string

// Define the names for resources.
var appServiceAppName = 'toy-website-${resourceNameSuffix}'
var appServicePlanName = 'toy-website'
var logAnalyticsWorkspaceName = 'workspace-${resourceNameSuffix}'
var applicationInsightsName = 'toywebsite'
var storageAccountName = 'mystorage${resourceNameSuffix}'
var storageAccountImagesBlobContainerName = 'toyimages'
var sqlServerName = 'toy-website-${resourceNameSuffix}'
var sqlDatabaseName = 'Toys'

// Define the connection string to access Azure SQL.
var sqlDatabaseConnectionString = 'Server=tcp:${sqlServer.properties.fullyQualifiedDomainName},1433;Initial Catalog=${sqlDatabase.name};Persist Security Info=False;User ID=${sqlServerAdministratorLogin};Password=${sqlServerAdministratorLoginPassword};MultipleActiveResultSets=False;Encrypt=True;TrustServerCertificate=False;Connection Timeout=30;'

// Define the SKUs for each component based on the environment type.
var environmentConfigurationMap = {
  Production: {
    appServicePlan: {
      sku: {
        name: 'S1'
        capacity: 1
      }
    }
    storageAccount: {
      sku: {
        name: 'Standard_LRS'
      }
    }
    sqlDatabase: {
      sku: {
        name: 'Standard'
        tier: 'Standard'
      }
    }
  }
  Test: {
    appServicePlan: {
      sku: {
        name: 'F1'
      }
    }
    storageAccount: {
      sku: {
        name: 'Standard_GRS'
      }
    }
    sqlDatabase: {
      sku: {
        name: 'Standard'
        tier: 'Standard'
      }
    }
  }
}

resource appServicePlan 'Microsoft.Web/serverfarms@2022-03-01' = {
  name: appServicePlanName
  ___location: ___location
  sku: environmentConfigurationMap[environmentType].appServicePlan.sku
}

resource appServiceApp 'Microsoft.Web/sites@2022-03-01' = {
  name: appServiceAppName
  ___location: ___location
  properties: {
    serverFarmId: appServicePlan.id
    httpsOnly: true
    siteConfig: {
      appSettings: [
        {
          name: 'APPINSIGHTS_INSTRUMENTATIONKEY'
          value: applicationInsights.properties.InstrumentationKey
        }
        {
          name: 'APPLICATIONINSIGHTS_CONNECTION_STRING'
          value: applicationInsights.properties.ConnectionString
        }
        {
          name: 'ReviewApiUrl'
          value: reviewApiUrl
        }
        {
          name: 'ReviewApiKey'
          value: reviewApiKey
        }
        {
          name: 'StorageAccountName'
          value: storageAccount.name
        }
        {
          name: 'StorageAccountBlobEndpoint'
          value: storageAccount.properties.primaryEndpoints.blob
        }
        {
          name: 'StorageAccountImagesContainerName'
          value: storageAccount::blobService::storageAccountImagesBlobContainer.name
        }
        {
          name: 'SqlDatabaseConnectionString'
          value: sqlDatabaseConnectionString
        }
      ]
    }
  }
}

resource logAnalyticsWorkspace 'Microsoft.OperationalInsights/workspaces@2022-10-01' = {
  name: logAnalyticsWorkspaceName
  ___location: ___location
}

resource applicationInsights 'Microsoft.Insights/components@2020-02-02' = {
  name: applicationInsightsName
  ___location: ___location
  kind: 'web'
  properties: {
    Application_Type: 'web'
    Request_Source: 'rest'
    Flow_Type: 'Bluefield'
    WorkspaceResourceId: logAnalyticsWorkspace.id
  }
}

resource storageAccount 'Microsoft.Storage/storageAccounts@2022-09-01' = {
  name: storageAccountName
  ___location: ___location
  kind: 'StorageV2'
  sku: environmentConfigurationMap[environmentType].storageAccount.sku

  resource blobService 'blobServices' = {
    name: 'default'

    resource storageAccountImagesBlobContainer 'containers' = {
      name: storageAccountImagesBlobContainerName

      properties: {
        publicAccess: 'Blob'
      }
    }
  }
}

resource sqlServer 'Microsoft.Sql/servers@2022-05-01-preview' = {
  name: sqlServerName
  ___location: ___location
  properties: {
    administratorLogin: sqlServerAdministratorLogin
    administratorLoginPassword: sqlServerAdministratorLoginPassword
  }
}

resource sqlServerFirewallRule 'Microsoft.Sql/servers/firewallRules@2022-05-01-preview' = {
  parent: sqlServer
  name: 'AllowAllWindowsAzureIps'
  properties: {
    endIpAddress: '0.0.0.0'
    startIpAddress: '0.0.0.0'
  }
}

resource sqlDatabase 'Microsoft.Sql/servers/databases@2022-05-01-preview' = {
  parent: sqlServer
  name: sqlDatabaseName
  ___location: ___location
  sku: environmentConfigurationMap[environmentType].sqlDatabase.sku
}

output appServiceAppName string = appServiceApp.name
output appServiceAppHostName string = appServiceApp.properties.defaultHostName
output storageAccountName string = storageAccount.name
output storageAccountImagesBlobContainerName string = storageAccount::blobService::storageAccountImagesBlobContainer.name
output sqlServerFullyQualifiedDomainName string = sqlServer.properties.fullyQualifiedDomainName
output sqlDatabaseName string = sqlDatabase.name

如果不是，则对其进行更新以匹配文件内容。

验证 deploy.yml 文件是否如下所示：

parameters:
- name: environmentType
  type: string
- name: deploymentDefaultLocation
  type: string
  default: westus3

stages:

- ${{ if ne(parameters.environmentType, 'Production') }}:
  - stage: Validate_${{parameters.environmentType}}
    displayName: Validate (${{parameters.environmentType}} Environment)
    jobs:
    - job: ValidateBicepCode
      displayName: Validate Bicep code
      variables:
      - group: ToyWebsite${{parameters.environmentType}}
      steps:
        - task: AzureResourceManagerTemplateDeployment@3
          name: RunPreflightValidation
          displayName: Run preflight validation
          inputs:
            connectedServiceName: ToyWebsite${{parameters.environmentType}}
            ___location: ${{parameters.deploymentDefaultLocation}}
            deploymentMode: Validation
            resourceGroupName: $(ResourceGroupName)
            csmFile: deploy/main.bicep
            overrideParameters: >
              -environmentType $(EnvironmentType)
              -reviewApiUrl $(ReviewApiUrl)
              -reviewApiKey $(ReviewApiKey)
              -sqlServerAdministratorLogin $(SqlServerAdministratorLogin)
              -sqlServerAdministratorLoginPassword $(SqlServerAdministratorLoginPassword)

- ${{ if eq(parameters.environmentType, 'Production') }}:
  - stage: Preview_${{parameters.environmentType}}
    displayName: Preview (${{parameters.environmentType}} Environment)
    jobs:
    - job: PreviewAzureChanges
      displayName: Preview Azure changes
      variables:
      - group: ToyWebsite${{parameters.environmentType}}
      steps:
        - task: AzureCLI@2
          name: RunWhatIf
          displayName: Run what-if
          inputs:
            azureSubscription: ToyWebsite${{parameters.environmentType}}
            scriptType: 'bash'
            scriptLocation: 'inlineScript'
            inlineScript: |
              az deployment group what-if \
                --resource-group $(ResourceGroupName) \
                --template-file deploy/main.bicep \
                --parameters environmentType=$(EnvironmentType) \
                             reviewApiUrl=$(ReviewApiUrl) \
                             reviewApiKey=$(ReviewApiKey) \
                             sqlServerAdministratorLogin=$(SqlServerAdministratorLogin) \
                             sqlServerAdministratorLoginPassword=$(SqlServerAdministratorLoginPassword)

- stage: Deploy_${{parameters.environmentType}}
  displayName: Deploy (${{parameters.environmentType}} Environment)
  jobs:
  - deployment: DeployWebsite
    displayName: Deploy website
    pool:
      vmImage: windows-latest
    variables:
    - group: ToyWebsite${{parameters.environmentType}}
    environment: ${{parameters.environmentType}}
    strategy:
      runOnce:
        deploy:
          steps:
            - checkout: self

            - task: AzureResourceManagerTemplateDeployment@3
              name: DeployBicepFile
              displayName: Deploy Bicep file
              inputs:
                connectedServiceName: ToyWebsite${{parameters.environmentType}}
                deploymentName: $(Build.BuildNumber)
                ___location: ${{parameters.deploymentDefaultLocation}}
                resourceGroupName: $(ResourceGroupName)
                csmFile: deploy/main.bicep
                overrideParameters: >
                  -environmentType $(EnvironmentType)
                  -reviewApiUrl $(ReviewApiUrl)
                  -reviewApiKey $(ReviewApiKey)
                  -sqlServerAdministratorLogin $(SqlServerAdministratorLogin)
                  -sqlServerAdministratorLoginPassword $(SqlServerAdministratorLoginPassword)
                deploymentOutputs: deploymentOutputs

            - bash: |
                echo "##vso[task.setvariable variable=appServiceAppName]$(echo $DEPLOYMENT_OUTPUTS | jq -r '.appServiceAppName.value')"
                echo "##vso[task.setvariable variable=appServiceAppHostName;isOutput=true]$(echo $DEPLOYMENT_OUTPUTS | jq -r '.appServiceAppHostName.value')"
                echo "##vso[task.setvariable variable=storageAccountName]$(echo $DEPLOYMENT_OUTPUTS | jq -r '.storageAccountName.value')"
                echo "##vso[task.setvariable variable=storageAccountImagesBlobContainerName]$(echo $DEPLOYMENT_OUTPUTS | jq -r '.storageAccountImagesBlobContainerName.value')"
                echo "##vso[task.setvariable variable=sqlServerFullyQualifiedDomainName]$(echo $DEPLOYMENT_OUTPUTS | jq -r '.sqlServerFullyQualifiedDomainName.value')"
                echo "##vso[task.setvariable variable=sqlDatabaseName]$(echo $DEPLOYMENT_OUTPUTS | jq -r '.sqlDatabaseName.value')"
              name: SaveDeploymentOutputs
              displayName: Save deployment outputs into variables
              env:
                DEPLOYMENT_OUTPUTS: $(deploymentOutputs)

            - task: AzureRmWebAppDeployment@4
              name: DeployWebsiteApp
              displayName: Deploy website
              inputs:
                appType: webApp
                ConnectionType: AzureRM
                azureSubscription: ToyWebsite${{parameters.environmentType}}
                ResourceGroupName: $(ResourceGroupName)
                WebAppName: $(appServiceAppName)
                Package: '$(Pipeline.Workspace)/website/publish.zip'

            - task: SqlAzureDacpacDeployment@1
              name: DeploySqlDatabaseDacpac
              displayName: Deploy DACPAC to database
              inputs:
                ConnectedServiceNameARM: ToyWebsite${{parameters.environmentType}}
                authenticationType: 'server'
                serverName: $(sqlServerFullyQualifiedDomainName)
                databaseName: $(sqlDatabaseName)
                sqlUsername: $(SqlServerAdministratorLogin)
                sqlPassword: $(SqlServerAdministratorLoginPassword)
                deployType: 'DacpacTask'
                deploymentAction: 'Publish'
                dacpacFile: '$(Pipeline.Workspace)/database/ToyCompany.Database.dacpac'

            - ${{ if ne(parameters.environmentType, 'Production') }}:
              - task: SqlAzureDacpacDeployment@1
                name: AddTestDataToDatabase
                displayName: Add test data to database
                inputs:
                  ConnectedServiceNameARM: ToyWebsite${{parameters.environmentType}}
                  authenticationType: 'server'
                  serverName: $(sqlServerFullyQualifiedDomainName)
                  databaseName: $(sqlDatabaseName)
                  sqlUsername: $(SqlServerAdministratorLogin)
                  sqlPassword: $(SqlServerAdministratorLoginPassword)
                  deployType: 'sqlTask'
                  sqlFile: 'deploy/sample-data/Toys.sql'

              - task: AzureCLI@2
                name: UploadSampleImages
                displayName: Upload sample images
                inputs:
                  azureSubscription: ToyWebsite${{parameters.environmentType}}
                  scriptType: 'bash'
                  scriptLocation: 'inlineScript'
                  inlineScript: |
                    az storage blob upload-batch \
                      --account-name $(storageAccountName) \
                      --destination $(storageAccountImagesBlobContainerName) \
                      --source 'deploy/sample-data/toyimages'

- stage: SmokeTest_${{parameters.environmentType}}
  displayName: Smoke Test (${{parameters.environmentType}} Environment)
  jobs:
  - job: SmokeTest
    displayName: Smoke test
    variables:
      appServiceAppHostName: $[ stageDependencies.Deploy_${{parameters.environmentType}}.DeployWebsite.outputs['DeployWebsite.SaveDeploymentOutputs.appServiceAppHostName'] ]
    steps:
      - task: PowerShell@2
        name: RunSmokeTests
        displayName: Run smoke tests
        inputs:
          targetType: inline
          script: |
            $container = New-PesterContainer `
              -Path 'deploy/Website.Tests.ps1' `
              -Data @{ HostName = '$(appServiceAppHostName)' }
            Invoke-Pester `
              -Container $container `
              -CI

      - task: PublishTestResults@2
        name: PublishTestResults
        displayName: Publish test results
        condition: always()
        inputs:
          testResultsFormat: NUnit
          testResultsFiles: 'testResults.xml'

如果不是，则对其进行更新以匹配文件内容。

保存对该文件所做的更改。
提交所做的更改并将其推送到 Git 存储库。在 Visual Studio Code 终端中，运行以下命令：
```
git add .
git commit -m "Add SQL database"
git push
```

运行管道

在浏览器中，转到“管道”。
选择管道的最新运行。

等待成功完成测试环境的所有阶段。请注意，版本验收测试现在也成功了。
在进入预览版（生产环境）阶段之前，等待管道再次暂停，因为这次需要获取其他变量组的权限。
选择“查看”，然后选择“允许”>“允许”。

预览版（生产环境）阶段成功完成。
在管道完成最后阶段时对其进行监视。

部署（生产环境）阶段成功完成，烟雾测试（生产环境）阶段也成功完成。

查看网站

选择 “部署”（测试环境） 阶段以打开管道日志。
选择“部署网站”步骤。

按住 Ctrl 键（在 macOS 上⌘ ），然后选择应用服务应用的 URL，在新的浏览器选项卡中打开它。
选择“玩具”。

请注意，示例数据显示在测试环境中。
对 部署（生产环境） 阶段的应用重复上述过程。

请注意，生产环境中未显示任何示例数据。

清理资源

请注意，完成练习后应移除相应资源，以免产生相关费用。

在 Visual Studio Code 终端中，运行以下命令：

az group delete --resource-group ToyWebsiteTest --yes --no-wait
az group delete --resource-group ToyWebsiteProduction --yes --no-wait

资源组将在后台删除。

Remove-AzResourceGroup -Name ToyWebsiteTest -Force
Remove-AzResourceGroup -Name ToyWebsiteProduction -Force