获取包含图层的页面。 此为只读属性。
语法
expression。 Page
表达 一个代表 Layers 对象的变量。
返回值
Page
备注
如果 Layers 集合位于母版中而不是页面中， 则 Page 属性返回 Nothing。 您无法设置 Layers 集合的 Page 属性。
示例
以下 Microsoft Visual Basic for Applications (VBA) 宏显示如何使用 Page 属性从各个其他对象返回 Page 对象。
Public Sub Page_Example()
Dim vsoPage1 As Visio.Page
Dim vsoPage2 As Visio.Page
Dim vsoTempPage As Visio.Page
Dim vsoLayer1 As Visio.Layer
Dim vsoLayer2 As Visio.Layer
Dim vsoLayers1 As Visio.Layers
Dim vsoLayers2 As Visio.Layers
'Set the current page name to MyPage1.
ActivePage.Name = "MyPage1"
'Use the Page property to return the current
'Page object from the Window object.
Set vsoPage1 = ActiveWindow.Page
'Verify that the expected page was received.
Debug.Print "The active window contains: " & vsoPage1.Name
'Add a second page named MyPage2.
Set vsoPage2 = ActiveDocument.Pages.Add
vsoPage2.Name = "MyPage2"
'Get the Layers collection from each page.
Set vsoLayers1 = vsoPage1.Layers
Set vsoLayers2 = vsoPage2.Layers
'Create a layer for each of the Layers collections.
Set vsoLayer1 = vsoLayers1.Add("ExampleLayer1")
Set vsoLayer2 = vsoLayers2.Add("ExampleLayer2")
'Use the Page property to return the Page object
'from a Layers object.
Set vsoTempPage = vsoLayers1.Page
'Verify that the expected page was received.
Debug.Print " vsoLayers1 is from: " & vsoTempPage.Name
'Use the Page property to return the Page object
'from a Layer object.
Set vsoTempPage = vsoLayer2.Page
'Verify that the expected page was received.
Debug.Print " vsoLayer2 is from: " & vsoTempPage.Name
'Set the active window's page to "MyPage1."
ActiveWindow.Page = "MyPage1"
End Sub
支持和反馈
有关于 Office VBA 或本文档的疑问或反馈？ 请参阅 Office VBA 支持和反馈，获取有关如何接收支持和提供反馈的指南。