通过

你当前正在访问 Microsoft Azure Global Edition 技术文档网站。 如果需要访问由世纪互联运营的 Microsoft Azure 中国技术文档网站，请访问 https://docs.azure.cn。

地理空间可视化效果

适用于：✅Azure 数据资源管理器Azure Monitor✅ Sentinel

可以将地理空间数据可视化为查询的一部分，使用 呈现运算符 作为地图上的点、馅饼或气泡。

有关地理空间聚类的详细信息，请参阅地理空间聚类。

例子

以下示例查找风暴事件并在地图上可视化 100 个点。

运行查询

StormEvents
| take 100
| project BeginLon, BeginLat
| render scatterchart with (kind = map)

地图上的示例风暴事件的屏幕截图。

以下示例可视化多个点系列，其中 [经度, 纬度] 对定义每个点，第三列定义序列。 在此示例中，系列为 EventType。

运行查询

StormEvents
| take 100
| project BeginLon, BeginLat, EventType
| render scatterchart with (kind = map)

地图上的示例风暴系列事件的屏幕截图。

以下示例在地图上可视化点系列。 如果结果中有多个列，则必须指定要用于 xcolumn（经度）、ycolumn（纬度）和系列的列。

注释

Kusto.Explorer仅支持多列可视化效果。

StormEvents
| take 100
| render scatterchart with (kind = map, xcolumn = BeginLon, ycolumns = BeginLat, series = EventType)

使用参数的示例风暴系列事件的屏幕截图。

以下示例使用 GeoJSON 动态值来可视化地图上的点，以定义点。

运行查询

StormEvents
| project BeginLon, BeginLat
| summarize by hash=geo_point_to_s2cell(BeginLon, BeginLat, 5)
| project geo_s2cell_to_central_point(hash)
| render scatterchart with (kind = map)

示例风暴 GeoJSON 事件的屏幕截图。

以下示例显示了 S2 单元格聚合的 storm 事件。 图表按一种颜色的位置聚合气泡中的事件。

运行查询

StormEvents
| project BeginLon, BeginLat, EventType
| where geo_point_in_circle(BeginLon, BeginLat, real(-81.3891), 28.5346, 1000 * 100)
| summarize count() by EventType, hash = geo_point_to_s2cell(BeginLon, BeginLat)
| project geo_s2cell_to_central_point(hash), count_
| extend Events = "count"
| render piechart with (kind = map)

气泡图上的风暴事件的屏幕截图。

以下示例显示了 S2 单元格聚合的 storm 事件。 图表按位置按饼图中的事件类型聚合事件。

注释

Kusto.Explorer中仅支持颜色轴可视化效果。

StormEvents
| project BeginLon, BeginLat, EventType
| where geo_point_in_circle(BeginLon, BeginLat, real(-81.3891), 28.5346, 1000 * 100)
| summarize count() by EventType, hash = geo_point_to_s2cell(BeginLon, BeginLat)
| project geo_s2cell_to_central_point(hash), EventType, count_
| render piechart with (kind = map)

Kusto.Explorer 中饼图上的 storm 事件的屏幕截图。

相关内容