如何使用包定义文件模板创建包

以下示例演示如何使用 Configuration Manager 中的包定义文件模板创建包和程序。 包定义文件模板包含用于创建 SMS_Package 和 SMS_Program 对象的默认值。 以下示例使用 SMS_PDF_Package 类和 GetPDFData 方法加载包定义文件模板信息并创建包和相关程序。

使用包定义文件模板创建包

1. 设置与 SMS 提供程序的连接。

2. 使用 SMS_PDF_Package 类创建新的包对象。

3. 填充任何其他包属性。

4. 加载程序信息并将每个程序与包相关联。

示例

以下示例方法使用包定义文件创建新包。

有关调用示例代码的信息，请参阅调用Configuration Manager代码片段。

Sub SWDCreatePDFPackage(connection, existingPDF_ID, newPackageSourceFlag, newPackageSourcePath)
    ' The PDF_ID must be passed in.
    ' The PDF_ID can be identified through the SMS_PDF_Package class.

    Dim newPDFPackage
    Dim returnCode
    Dim newPackage
    Dim newPackagePath
    Dim packageID
    Dim program
    Dim arrayOfPrograms

    ' Package Creation
    ' ----------------
    ' Create new SMS_PDF_Package instance.
    Set newPDFPackage = connection.Get("SMS_PDF_Package")

    ' Load the Package Definition File data using the GetPDFData method.
    returnCode = newPDFPackage.GetPDFData(existingPDF_ID, newPackage, arrayOfPrograms)

    ' Assign any additional package properties.
    newPackage.PkgSourceFlag = newPackageSourceFlag
    newPackage.PkgSourcePath = newPackageSourcePath

    ' Save the package path and get the Package ID.
    Set newPackagePath = newPackage.Put_
    packageID = newPackagePath.Keys("PackageID")

    ' Program Creation
    ' -----------------
    ' Enumerate through the program array and create the programs.
    For Each program In arrayOfPrograms
        program.PackageID = packageID
        program.Put_
    Next

End Sub

示例方法具有以下参数：

可靠编程

有关错误处理的详细信息，请参阅关于Configuration Manager错误。

另请参阅

SMS_SCI_Component服务器 WMI 类的软件分发概述