<xsl:namespace-alias>의 예제

2008-08-22

이 예제에서는 xsl: 접두사가 스타일시트에서 같은 네임스페이스 URI에 대해 바인딩되는 경우 리터럴 결과 트리에서 <xsl:namespace-alias>를 사용하여 alt: 접두사를 XSLT 네임스페이스의 별칭으로 선언하는 방법을 보여 줍니다. 다른 XSLT 스타일시트가 출력으로 나타납니다.

XML 파일(mymin.xml)

<?xml version='1.0'?>
<?xml-stylesheet type="text/xsl" href="alias.xsl"?>
<myelem/>

XSLT 파일(alias.xsl)

<?xml version='1.0'?>
<xsl:stylesheet version="1.0"
      xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
      xmlns:alt="http://www.w3.org/1999/XSL/Transform-alternate">

<xsl:namespace-alias stylesheet-prefix="alt" result-prefix="xsl"/>
<xsl:param name="browser" select="'InternetExplorer'"/>

<xsl:template match="/">
   <alt:stylesheet>
      <xsl:choose>
         <xsl:when test="$browser='InternetExplorer'">
            <alt:import href="IERoutines.xsl"/>
            <alt:template match="/">
               <div>
                  <alt:call-template name="showTable"/>
               </div>
            </alt:template>
         </xsl:when>
         <xsl:otherwise>
            <alt:import href="OtherBrowserRoutines.xsl"/>
            <alt:template match="/">
               <div>
                  <alt:call-template name="showTable"/>
               </div>
            </alt:template>
         </xsl:otherwise>
      </xsl:choose>
   </alt:stylesheet>
</xsl:template>
</xsl:stylesheet>

JScript 파일(test.js)

var xmldoc = new ActiveXObject("Msxml2.DOMDocument.6.0");
xmldoc.async=false;
xmldoc.load("mymin.xml");

var xsldoc= new ActiveXObject("Msxml2.DOMDocument.6.0");
xsldoc.async = false;
xsldoc.load("alias.xsl");

var outfile = new ActiveXObject("Msxml2.DOMDocument.6.0");
outfile.async=false;

var strResult;
strResult = xmldoc.transformNode(xsldoc);
outfile.loadXML(strResult);
outfile.save("output.xsl");

WScript.Echo("Output.xsl was made.");

실습

위의 XML 파일을 복사하여 텍스트 파일에 붙여넣습니다. 이 파일을 mymin.xml로 로컬 드라이브의 디렉터리에 저장합니다.
위의 XSLT 파일을 복사하여 텍스트 파일에 붙여넣습니다. 이 파일을 alias.xsl로 같은 디렉터리에 저장합니다.
위의 JScript 목록을 복사하여 텍스트 파일에 붙여넣습니다. 이 파일을 test.js로 같은 디렉터리에 저장합니다.
Windows 탐색기에서 test.js 파일을 두 번 클릭하여 응용 프로그램을 실행합니다. 또는 명령 프롬프트에 "test.js"를 입력하여 응용 프로그램을 실행할 수도 있습니다.

참고

Windows 2000 또는 Windows XP 이외의 운영 체제에서는 Windows Scripting Host(wscript.exe)를 설치해야 합니다.

다음 출력 파일 output.xsl이 로컬 드라이브에 나타납니다.
출력이 아래 표시된 것과 같은지 확인하십시오.

출력

test.js를 실행하면 메시지 상자나 콘솔 창에 다음 출력이 나타나야 합니다.

Output.xsl was made.

또한 프로세서는 샘플 파일을 저장한 폴더에 다음 스트림을 XSLT 파일 output.xsl로 출력합니다. 여기서는 명확히 나타내기 위해 공백을 추가했습니다.

<?xml version="1.0" encoding="UTF-16"?>
<xsl:stylesheet 
      xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:import href="IERoutines.xsl" />

<xsl:template match="/">
   <div>
      <xsl:call-template name="showTable" />
   </div>
</xsl:template>

</xsl:stylesheet>

참고 항목

참조

<xsl:import> 요소
<xsl:include> 요소