다음을 통해 공유

방법: 메모리를 절약하기 위해 사용자 지정 이벤트 선언(Visual Basic)

애플리케이션에서 메모리 사용량을 낮게 유지하는 것이 중요한 몇 가지 상황이 있습니다. 사용자 지정 이벤트를 사용하면 애플리케이션이 처리하는 이벤트에 대해서만 메모리를 사용할 수 있습니다.

기본적으로 클래스가 이벤트를 선언할 때 컴파일러는 이벤트 정보를 저장할 필드에 대한 메모리를 할당합니다. 클래스에 사용되지 않는 이벤트가 많은 경우 불필요하게 메모리를 차지합니다.

Visual Basic에서 제공하는 이벤트의 기본 구현을 사용하는 대신 사용자 지정 이벤트를 사용하여 메모리 사용량을 더 신중하게 관리할 수 있습니다.

예시

이 예제에서 클래스는 필드에 저장된 EventHandlerList 클래스의 Events 인스턴스 하나를 사용하여 사용 중인 이벤트에 대한 정보를 저장합니다. 클래스는 EventHandlerList 대리자를 포함하도록 설계된 최적화된 목록 클래스입니다.

클래스의 모든 이벤트는 필드를 사용하여 Events 각 이벤트를 처리하는 메서드를 추적합니다.

Public Class MemoryOptimizedBaseControl
    ' Define a delegate store for all event handlers.
    Private Events As New System.ComponentModel.EventHandlerList

    ' Define the Click event to use the delegate store.
    Public Custom Event Click As EventHandler
        AddHandler(ByVal value As EventHandler)
            Events.AddHandler("ClickEvent", value)
        End AddHandler
        RemoveHandler(ByVal value As EventHandler)
            Events.RemoveHandler("ClickEvent", value)
        End RemoveHandler
        RaiseEvent(ByVal sender As Object, ByVal e As EventArgs)
            CType(Events("ClickEvent"), EventHandler).Invoke(sender, e)
        End RaiseEvent
    End Event

    ' Define the DoubleClick event to use the same delegate store.
    Public Custom Event DoubleClick As EventHandler
        AddHandler(ByVal value As EventHandler)
            Events.AddHandler("DoubleClickEvent", value)
        End AddHandler
        RemoveHandler(ByVal value As EventHandler)
            Events.RemoveHandler("DoubleClickEvent", value)
        End RemoveHandler
        RaiseEvent(ByVal sender As Object, ByVal e As EventArgs)
            CType(Events("DoubleClickEvent"), EventHandler).Invoke(sender, e)
        End RaiseEvent
    End Event

    ' Define additional events to use the same delegate store.
    ' ...
End Class

참고하십시오