다음을 통해 공유

방법: 확장명별 파일 그룹화(LINQ)(Visual Basic)

이 예제에서는 LINQ를 사용하여 파일 또는 폴더 목록에서 고급 그룹화 및 정렬 작업을 수행하는 방법을 보여 줍니다. 또한 콘솔 창에서 Skip 및 Take 메서드를 사용하여 출력을 페이지하는 방법을 보여 줍니다.

예시

다음 쿼리는 지정된 디렉터리 트리의 내용을 파일 이름 확장명별로 그룹화하는 방법을 보여 줍니다.

Module GroupByExtension  
    Public Sub Main()  
  
        ' Root folder to query, along with all subfolders.  
        Dim startFolder As String = "C:\program files\Microsoft Visual Studio 9.0\VB\"  
  
        ' Used in WriteLine() to skip over startfolder in output lines.  
        Dim rootLength As Integer = startFolder.Length  
  
        'Take a snapshot of the folder contents  
        Dim dir As New System.IO.DirectoryInfo(startFolder)  
        Dim fileList = dir.GetFiles("*.*", System.IO.SearchOption.AllDirectories)  
  
        ' Create the query.  
        Dim queryGroupByExt = From file In fileList _  
                          Group By file.Extension.ToLower() Into fileGroup = Group _  
                          Order By ToLower _  
                          Select fileGroup  
  
        ' Execute the query. By storing the result we can  
        ' page the display with good performance.  
        Dim groupByExtList = queryGroupByExt.ToList()  
  
        ' Display one group at a time. If the number of
        ' entries is greater than the number of lines  
        ' in the console window, then page the output.  
        Dim trimLength = startFolder.Length  
        PageOutput(groupByExtList, trimLength)  
  
    End Sub  
  
    ' Pages console display for large query results. No more than one group per page.  
    ' This sub specifically works with group queries of FileInfo objects  
    ' but can be modified for any type.  
    Sub PageOutput(ByVal groupQuery, ByVal charsToSkip)  
  
        ' "3" = 1 line for extension key + 1 for "Press any key" + 1 for input cursor.  
        Dim numLines As Integer = Console.WindowHeight - 3  
        ' Flag to indicate whether there are more results to display  
        Dim goAgain As Boolean = True  
  
        For Each fg As IEnumerable(Of System.IO.FileInfo) In groupQuery  
            ' Start a new extension at the top of a page.  
            Dim currentLine As Integer = 0  
  
            Do While (currentLine < fg.Count())  
                Console.Clear()  
                Console.WriteLine(fg(0).Extension)  
  
                ' Get the next page of results  
                ' No more than one filename per page  
                Dim resultPage = From file In fg _  
                                Skip currentLine Take numLines  
  
                ' Execute the query. Trim the display output.  
                For Each line In resultPage  
                    Console.WriteLine(vbTab & line.FullName.Substring(charsToSkip))  
                Next  
  
                ' Advance the current position  
                currentLine = numLines + currentLine  
  
                ' Give the user a chance to break out of the loop  
                Console.WriteLine("Press any key for next page or the 'End' key to exit.")  
                Dim key As ConsoleKey = Console.ReadKey().Key  
                If key = ConsoleKey.End Then  
                    goAgain = False  
                    Exit For  
                End If  
            Loop  
        Next  
    End Sub  
End Module

프로그램의 출력은 로컬 파일 시스템의 세부 사항과 startFolder 설정에 따라 길어질 수 있습니다. 모든 결과를 볼 수 있도록 하기 위해 이 예제에서는 결과를 페이지를 넘기는 방법을 보여 줍니다. Windows 및 웹 애플리케이션에 동일한 기술을 적용할 수 있습니다. 코드가 그룹의 항목을 페이지로 표시하므로 중첩된 For Each 루프가 필요합니다. 또한 목록에서 현재 위치를 계산하고 사용자가 페이징을 중지하고 프로그램을 종료할 수 있도록 하는 몇 가지 추가 논리도 있습니다. 이 경우 페이징 쿼리는 원래 쿼리의 캐시된 결과에 대해 실행됩니다. LINQ to SQL과 같은 다른 컨텍스트에서는 이러한 캐싱이 필요하지 않습니다.

코드 컴파일

Visual Basic 콘솔 애플리케이션 프로젝트를 만들어서, System.Linq 네임스페이스에 대한 Imports 문을 추가합니다.

참고하십시오