Func 및 Action 제네릭 대리자(Visual Basic)에 대한 변환 사용

이러한 예제는 Func 및 Action 제네릭 대리자에서 공변성 및 반공변성을 사용하여 메서드를 재사용하고 코드에서 더 많은 유연성을 제공하는 방법을 보여 줍니다.

공변성 및 반공변에 대한 자세한 내용은 대리자에서의 분산(Visual Basic)을 참조하세요.

공변 형식 매개 변수와 대리자 사용

다음 예제에서는 제네릭 Func 대리자에서 공변성 지원의 이점을 보여 줍니다. 메서드는 FindByTitle 형식의 매개 변수를 받아 String 형식의 객체를 반환합니다. 그러나 Func(Of String, Person)가 Employee을(를) 상속하므로 이 메서드를 Person 대리자에게 할당할 수 있습니다.

' Simple hierarchy of classes.
Public Class Person
End Class

Public Class Employee
    Inherits Person
End Class

Class Finder
    Public Shared Function FindByTitle(
        ByVal title As String) As Employee
        ' This is a stub for a method that returns
        ' an employee that has the specified title.
        Return New Employee
    End Function

    Sub Test()
        ' Create an instance of the delegate without using variance.
        Dim findEmployee As Func(Of String, Employee) =
            AddressOf FindByTitle

        ' The delegate expects a method to return Person,
        ' but you can assign it a method that returns Employee.
        Dim findPerson As Func(Of String, Person) =
            AddressOf FindByTitle

        ' You can also assign a delegate
        ' that returns a more derived type to a delegate
        ' that returns a less derived type.
        findPerson = findEmployee
    End Sub
End Class

반공변 형식 매개 변수와 대리자 사용

다음 예제에서는 제네릭 Action 대리자에서 반변성 지원의 이점을 보여 줍니다. 메서드는 AddToContacts 유형의 매개 변수를 Person 받습니다. 그러나 Action(Of Employee)가 Employee을(를) 상속하므로 이 메서드를 Person 대리자에게 할당할 수 있습니다.

Public Class Person
End Class

Public Class Employee
    Inherits Person
End Class

Class AddressBook
    Shared Sub AddToContacts(ByVal person As Person)
        ' This method adds a Person object
        ' to a contact list.
    End Sub

    Sub Test()
        ' Create an instance of the delegate without using variance.
        Dim addPersonToContacts As Action(Of Person) =
            AddressOf AddToContacts

        ' The Action delegate expects
        ' a method that has an Employee parameter,
        ' but you can assign it a method that has a Person parameter
        ' because Employee derives from Person.
        Dim addEmployeeToContacts As Action(Of Employee) =
            AddressOf AddToContacts

        ' You can also assign a delegate
        ' that accepts a less derived parameter
        ' to a delegate that accepts a more derived parameter.
        addEmployeeToContacts = addPersonToContacts
    End Sub
End Class

참고하십시오

• 공변성 및 반공변성(Visual Basic)
• 제네릭