次の方法で共有

boolean 関数

引数をブール値に変換します。

boolean boolean(arg)

解説

この関数は、次の規則に従って引数をブール値に変換します。

  • 引数が負の数または正の数である場合は、ブール値 true に変換されます。引数がゼロまたは NaN value である場合は、false に変換されます。

  • 引数が空でないノード セットである場合は、true に変換されます。空のノード セットは、false に変換されます。

  • 引数が空でない文字列である場合は、true に変換されます。空の文字列は false に変換されます。

  • 引数が 4 つの基本型以外の型のオブジェクトである場合は、その型に応じた方法でブール値に変換されます。

例

XML ファイル

なし。XSLT ファイルは自身を呼び出します。

サンプル XML ファイル books.xml を使用し、href 属性を変更して bool.xsl を参照する場合、boolean(//book) は true として解決されます。

XSLT ファイル (bool.xsl)

<?xml version='1.0'?>
<?xml-stylesheet type="text/xsl" href="bool.xsl"?>
<xsl:stylesheet version="1.0"
      xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="html"/>

<xsl:template match="/">
    <html>
       <body>
          <h3>boolean() Function</h3>
          
          <ul>
             <li><b>boolean(0)</b> = 
                <xsl:value-of select="boolean(0)"/>
             </li>
             <li><b>boolean(1)</b> = 
                <xsl:value-of select="boolean(1)"/>
             </li>
             <li><b>boolean(-100)</b> = 
                <xsl:value-of select="boolean(-100)"/>
             </li>
             <li><b>boolean(100)</b> = 
                <xsl:value-of select="boolean(100)"/>
             </li>
             <li><b>boolean(NaN)</b> = 
                <xsl:value-of select="boolean(NaN)"/>
             </li>
             <li><b>boolean('hello')</b> = 
                <xsl:value-of select="boolean('hello')"/>
             </li>
             <li><b>boolean('')</b> = 
                <xsl:value-of select="boolean('')"/>
             </li>
             <li><b>boolean(//book)</b> = 
                <xsl:value-of select="boolean(//book)"/>
             </li>
             <li><b>boolean(//notfound)</b> = 
                <xsl:value-of select="boolean(//notfound)"/>
             </li>
          </ul>
       </body>
    </html>
</xsl:template>

</xsl:stylesheet>

書式付き出力

boolean() 関数

  • boolean(0) = false

  • boolean(1) = true

  • boolean(-100) = true

  • boolean(100) = true

  • boolean(NaN) = false

  • boolean('hello') = true

  • boolean('') = false

  • boolean(//book) = false

  • boolean(//notfound) = false

プロセッサ出力

<html>

<body>

<h3>boolean() Function</h3>

<ul>

<li><b>boolean(0)</b> =

false</li>

<li><b>boolean(1)</b> =

true</li>

<li><b>boolean(-100)</b> =

true</li>

<li><b>boolean(100)</b> =

true</li>

<li><b>boolean(NaN)</b> =

false</li>

<li><b>boolean('hello')</b> =

true</li>

<li><b>boolean('')</b> =

false</li>

<li><b>boolean(//book)</b> =

true</li>

<li><b>boolean(//notfound)</b> =

false</li>

</ul>

</body>

</html>

参照

リファレンス

XML データ型リファレンス

概念

NaN 値