次の方法で共有

Chart.Axes メソッド (Project)

オブジェクトを返すメソッドです。単一の軸、またはグラフのすべての軸を返します。

構文

式。軸 (種類、 AxisGroup)

expression は Chart オブジェクトを表す変数です。

パラメーター

名前 必須 / オプション データ型 説明
Type 省略可能 バリアント型 (Variant) 返す軸を指定します。 次のいずれかの Office.XlAxisType 定数を指定できます。xlValue、xlCategory、または xlSeriesAxis (xlSeriesAxis は 3D グラフでのみ有効です)。
AxisGroup オプション Office.XlAxisGroup 軸のグループを指定します。 既定値は xlPrimary です。つまり、 AxisGroup 引数を省略すると、プライマリ グループが使用されます。 3D グラフの軸グループは 1 つだけです。
Type 省略可能 バリアント型
AxisGroup オプション XLAXISGROUP

戻り値

Object

例

SetAxisTitle マクロは、グラフのカテゴリ軸に軸ラベルを追加します。

Sub SetAxisTitle()
    Dim chartShape As Shape
    Dim reportName As String
    
    reportName = "Simple scalar chart"
    
    Set chartShape = ActiveProject.Reports(reportName).Shapes(1)
    
    With chartShape.Chart.Axes(xlCategory)
        .HasTitle = True
        .AxisTitle.Text = "Task"
    End With
End Sub

AddCategoryGridlines マクロは、グラフのカテゴリ軸に目盛線を追加します。

Sub AddCategoryGridlines()
    Dim chartShape As Shape
    Dim reportName As String
    
    reportName = "Simple scalar chart"
    
    Set chartShape = ActiveProject.Reports(reportName).Shapes(1)
    
    chartShape.Chart.Axes(xlCategory).HasMajorGridlines = True
End Sub

RemoveGridlines マクロは、カテゴリ軸と値軸の両方から主目盛線を削除します。

Sub RemoveGridlines()
    Dim chartShape As Shape
    Dim reportName As String
    Dim axes As Object
    Dim a As Object
    
    reportName = "Simple scalar chart"
    
    Set chartShape = ActiveProject.Reports(reportName).Shapes(1)
    
    chartShape.Chart.Axes(xlCategory).HasMajorGridlines = False
    chartShape.Chart.Axes(xlValue).HasMajorGridlines = False
End Sub

サポートとフィードバック

Office VBA またはこの説明書に関するご質問やフィードバックがありますか？ サポートの受け方およびフィードバックをお寄せいただく方法のガイダンスについては、Office VBA のサポートおよびフィードバックを参照してください。