WMI を使用してConfiguration Manager オブジェクトを変更する方法

オブジェクトの SWbemObject オブジェクトを使用してプロパティを変更することで、Configuration Manager オブジェクトをConfiguration Managerで変更します。

Configuration Manager オブジェクトを変更するには

1. SMS プロバイダーへの接続を設定します。 詳細については、「WMI を使用してConfiguration Managerで SMS プロバイダーに接続する方法」を参照してください。

2. 手順 1 から取得した SWbemServices オブジェクトを使用して 、Get メソッドを呼び出し、目的のオブジェクトのクラスとキー情報を指定します。 これにより、オブジェクトを表す SWbemObject が 返されます。

3. SWbemObject を使用して、オブジェクトのプロパティを更新します。

4. Put_を呼び出して、SMS プロバイダー内のオブジェクトを更新します。

例

次の VBScript コード例では、パッケージ (SMS_Package) オブジェクトを取得し、パッケージの説明を変更してから、変更を SMS プロバイダーにコミットします。 この例では、パッケージは SWbemServices オブジェクト Get の呼び出しによって 取得されます。 クエリを使用してパッケージを取得することもできます。 詳細については、「WMI を使用して同期Configuration Manager クエリを実行する方法」を参照してください。

サンプル コードの呼び出しについては、「Configuration Manager コード スニペットの呼び出し」を参照してください。

Sub ModifyPackageDescription (connection, packageID, description)

    On Error Resume Next
    Dim package

    ' Get the package.
    Set package = connection.Get("SMS_Package.PackageID='" & packageID & "'")
    If Err.Number<>0 Then
        Wscript.Echo "Couldn't get package " + packageID
        Exit Sub
    End If

    Wscript.Echo "Package Name: " + package.Name
    Wscript.Echo "Current Description: " + package.Description

    ' Update and commit the package.
    package.Description = description

    package.Put_
    If Err.Number<>0 Then
        WScript.Echo "Couldn't commit the package"
        Exit Sub
    End If

    Wscript.Echo "New Description: " + package.Description
End Sub

この例のメソッドには、次のパラメーターがあります。

関連項目

Windows 管理インストルメンテーションオブジェクトの概要WMI を使用してConfiguration Manager オブジェクト クラス メソッドを呼び出す方法 WMI を使用してConfiguration Managerで SMS プロバイダーに接続する方法 WMI を使用してConfiguration Manager オブジェクトを作成する方法WMI を使用してConfiguration Manager オブジェクトを削除する WMIを使用して非同期Configuration Manager クエリを実行する方法 WMI を使用して同期Configuration Manager クエリを実行する方法 Configuration ManagerWMI を使用したオブジェクト WMIを使用した遅延プロパティの読み取り方法