次の方法で共有

方法: 変換演算子を定義する (Visual Basic)

クラスまたは構造体を定義した場合は、クラスまたは構造体の型と別のデータ型 ( Integer、 Double、 Stringなど) の間で型変換演算子を定義できます。

クラスまたは構造体内で CType 関数 プロシージャとして型変換を定義します。 すべての変換手順は Public Sharedする必要があり、各変換プロシージャで 拡大 または 縮小を指定する必要があります。

クラスまたは構造体に対する演算子の定義は、演算子 のオーバーロード とも呼ばれます。

例

次の例では、 digit と呼ばれる構造体と Byteの間の変換演算子を定義します。

Public Structure digit
Private dig As Byte
    Public Sub New(ByVal b As Byte)
        If (b < 0 OrElse b > 9) Then Throw New System.ArgumentException(
            "Argument outside range for Byte")
        Me.dig = b
    End Sub
    Public Shared Widening Operator CType(ByVal d As digit) As Byte
        Return d.dig
    End Operator
    Public Shared Narrowing Operator CType(ByVal b As Byte) As digit
        Return New digit(b)
    End Operator
End Structure

次のコードを使用して、 digit 構造をテストできます。

Public Sub consumeDigit()
    Dim d1 As New digit(4)
    Dim d2 As New digit(7)
    Dim d3 As digit = CType(CByte(3), digit)
    Dim s As String = "Initial 4 generates " & CStr(CType(d1, Byte)) &
          vbCrLf & "Initial 7 generates " & CStr(CType(d2, Byte)) &
          vbCrLf & "Converted 3 generates " & CStr(CType(d3, Byte))
    Try
        Dim d4 As digit
        d4 = CType(CType(d1, Byte) + CType(d2, Byte), digit)
    Catch e4 As System.Exception
        s &= vbCrLf & "4 + 7 generates " & """" & e4.Message & """"
    End Try
    Try
        Dim d5 As digit = CType(CByte(10), digit)
    Catch e5 As System.Exception
        s &= vbCrLf & "Initial 10 generates " & """" & e5.Message & """"
    End Try
    MsgBox(s)
End Sub

こちらも参照ください