フォルダー内のファイルの内容を照会する方法 (LINQ) (Visual Basic)

この例では、指定したディレクトリ ツリー内のすべてのファイルに対してクエリを実行し、各ファイルを開き、その内容を検査する方法を示します。 この種の手法を使用して、ディレクトリ ツリーの内容のインデックスまたは逆インデックスを作成できます。 この例では、単純な文字列検索を実行します。 ただし、より複雑な型のパターン マッチングは、正規表現を使用して実行できます。 詳細については、「 方法: LINQ クエリと正規表現を組み合わせる (Visual Basic)」を参照してください。

例

Imports System.IO

Module Module1
    'QueryContents
    Public Sub Main()

        ' Modify this path as necessary.
        Dim startFolder = "C:\Program Files (x86)\Microsoft Visual Studio 14.0"

        ' Take a snapshot of the folder contents.
        Dim dir As New DirectoryInfo(startFolder)
        Dim fileList = dir.GetFiles("*.*", SearchOption.AllDirectories)

        Dim searchTerm = "Welcome"

        ' Search the contents of each file.
        ' A regular expression created with the Regex class
        ' could be used instead of the Contains method.
        Dim queryMatchingFiles = From file In fileList _
                                 Where file.Extension = ".html" _
                                 Let fileText = GetFileText(file.FullName) _
                                 Where fileText.Contains(searchTerm) _
                                 Select file.FullName

        Console.WriteLine("The term " & searchTerm & " was found in:")

        ' Execute the query.
        For Each filename In queryMatchingFiles
            Console.WriteLine(filename)
        Next

        ' Keep the console window open in debug mode.
        Console.WriteLine("Press any key to exit")
        Console.ReadKey()

    End Sub

    ' Read the contents of the file. This is done in a separate
    ' function in order to handle potential file system errors.
    Function GetFileText(name As String) As String

        ' If the file has been deleted, the right thing
        ' to do in this case is return an empty string.
        Dim fileContents = String.Empty

        ' If the file has been deleted since we took
        ' the snapshot, ignore it and return the empty string.
        If File.Exists(name) Then
            fileContents = File.ReadAllText(name)
        End If

        Return fileContents

    End Function
End Module

コードをコンパイルする

Visual Basic コンソール アプリケーション プロジェクトを作成し、コード サンプルをコピーして貼り付け、プロジェクトのプロパティで Startup オブジェクトの値を調整します。

こちらも参照ください

• LINQ to Objects (Visual Basic)
• LINQ とファイル ディレクトリ (Visual Basic)