次の方法で共有

方法: 文字列内の文字を照会する (LINQ) (Visual Basic)

String クラスはジェネリック IEnumerable<T> インターフェイスを実装するため、任意の文字列を一連の文字として照会できます。 ただし、これは LINQ の一般的な使用ではありません。 複雑なパターン マッチング操作の場合は、 Regex クラスを使用します。

例

次の例では、文字列に対してクエリを実行して、文字列に含まれる数値の桁数を決定します。 クエリは、最初に実行された後に "再利用" されることに注意してください。 これは、クエリ自体に実際の結果が格納されないためです。

Class QueryAString

    Shared Sub Main()

        ' A string is an IEnumerable data source.
        Dim aString As String = "ABCDE99F-J74-12-89A"

        ' Select only those characters that are numbers
        Dim stringQuery = From ch In aString
                          Where Char.IsDigit(ch)
                          Select ch
        ' Execute the query
        For Each c As Char In stringQuery
            Console.Write(c & " ")
        Next

        ' Call the Count method on the existing query.
        Dim count As Integer = stringQuery.Count()
        Console.WriteLine(System.Environment.NewLine & "Count = " & count)

        ' Select all characters before the first '-'
        Dim stringQuery2 = aString.TakeWhile(Function(c) c <> "-")

        ' Execute the second query
        For Each ch In stringQuery2
            Console.Write(ch)
        Next

        Console.WriteLine(System.Environment.NewLine & "Press any key to exit")
        Console.ReadKey()
    End Sub
End Class
' Output:
' 9 9 7 4 1 2 8 9
' Count = 8
' ABCDE99F

コードをコンパイルする

System.Linq 名前空間の Imports ステートメントを使用して、Visual Basic コンソール アプリケーション プロジェクトを作成します。

こちらも参照ください