デリゲートでの分散の使用 (Visual Basic)

デリゲートにメソッドを割り当てると、 共変性 と 反変性 によって、デリゲート型とメソッド シグネチャを柔軟に照合できます。 共変性により、メソッドの戻り値の型の派生を、デリゲートに定義されている型よりも強くできます。 反変性により、デリゲート型のメソッドよりも派生度の低いパラメーター型を持つメソッドが許可されます。

例 1: 共変性

説明

この例では、デリゲートシグネチャの戻り値の型から派生した戻り値の型を持つメソッドでデリゲートを使用する方法を示します。 DogsHandlerによって返されるデータ型は、デリゲートで定義されているDogs型から派生するMammals型です。

コード

Class Mammals
End Class

Class Dogs
    Inherits Mammals
End Class
Class Test
    Public Delegate Function HandlerMethod() As Mammals
    Public Shared Function MammalsHandler() As Mammals
        Return Nothing
    End Function
    Public Shared Function DogsHandler() As Dogs
        Return Nothing
    End Function
    Sub Test()
        Dim handlerMammals As HandlerMethod = AddressOf MammalsHandler
        ' Covariance enables this assignment.
        Dim handlerDogs As HandlerMethod = AddressOf DogsHandler
    End Sub
End Class

例 2: 反変性

説明

この例は、型がデリゲート シグネチャ パラメーター型の基本データ型であるパラメーターを持つメソッドでデリゲートを使用する方法を示しています。 反変性では、個別のハンドラーの代わりに 1 つのイベント ハンドラーを使用できます。 次の例では、2 つのデリゲートを使用します。

• KeyEventHandler イベントのシグネチャを定義するデリゲート。 そのシグネチャは次のとおりです。

  Public Delegate Sub KeyEventHandler(sender As Object, e As KeyEventArgs)
  

• MouseEventHandler イベントのシグネチャを定義するデリゲート。 そのシグネチャは次のとおりです。

  Public Delegate Sub MouseEventHandler(sender As Object, e As MouseEventArgs)
  

この例では、 EventArgs パラメーターを持つイベント ハンドラーを定義し、それを使用して Button.KeyDown イベントと Button.MouseClick イベントの両方を処理します。 これは、 EventArgs が KeyEventArgs と MouseEventArgsの両方の基本型であるためです。

コード

' Event handler that accepts a parameter of the EventArgs type.
Private Sub MultiHandler(ByVal sender As Object,
                         ByVal e As System.EventArgs)
    Label1.Text = DateTime.Now
End Sub

Private Sub Form1_Load(ByVal sender As System.Object,
    ByVal e As System.EventArgs) Handles MyBase.Load

    ' You can use a method that has an EventArgs parameter,
    ' although the event expects the KeyEventArgs parameter.
    AddHandler Button1.KeyDown, AddressOf MultiHandler

    ' You can use the same method
    ' for the event that expects the MouseEventArgs parameter.
    AddHandler Button1.MouseClick, AddressOf MultiHandler
End Sub

こちらも参照ください

• デリゲートの分散 (Visual Basic)
• Func デリゲートと Action 汎用デリゲートの分散の使用 (Visual Basic)