Terraform を使用して PostgreSQL フレキシブルサーバーデータベースをデプロイする

2025-04-30

次の Terraform と Terraform プロバイダーのバージョンでテストされた記事:

Terraform を使用すると、クラウドインフラストラクチャの定義、プレビュー、デプロイが可能になります。 Terraform を使用して、 HCL 構文を使用して構成ファイルを作成します。 HCL 構文を使用すると、クラウドプロバイダー (Azure など) とクラウドインフラストラクチャを構成する要素を指定できます。構成ファイルを作成したら、インフラストラクチャの変更をデプロイする前にプレビューできる 実行プラン を作成します。変更を確認したら、実行プランを適用してインフラストラクチャをデプロイします。

この記事では、Terraform を使用して PostgreSQL フレキシブルサーバーデータベースをデプロイする方法について説明します。

この記事では、次の方法について説明します。

azurerm_resource_groupを使用して Azure リソースグループを作成する
azurerm_virtual_networkを使用して Azure 仮想ネットワーク (VNet) を作成する
azurerm_network_security_groupを使用して Azure ネットワークセキュリティグループ (NSG) を作成する
Azure サブネット azurerm_subnetを作成する
azurerm_subnet_network_security_group_associationを使用して Azure サブネットネットワークセキュリティグループ (NSG) を作成する
azurerm_private_dns_zoneを使用して Azure DNS 内にプライベート DNS ゾーンを定義する
azurerm_private_dns_zone_virtual_network_linkを使用してプライベート DNS ゾーンの VNet リンクを定義する
azurerm_postgresql_flexible_serverを使用してデータベースを実行する Azure PostgreSQL フレキシブルサーバーをデプロイする
azurerm_postgresql_flexible_server_databaseを使用して Azure PostgreSQL データベースをインスタンス化する

注

この記事のコード例は、 Azure Terraform GitHub リポジトリにあります。

1. 環境を構成する

Azure サブスクリプション: Azure サブスクリプションをお持ちでない場合は、開始する前に無料アカウントを作成してください。

Terraform の構成: まだ構成していない場合は、次のいずれかのオプションを使用して Terraform を構成します。
- Bash を使用して Azure Cloud Shell で Terraform を構成する
- PowerShell を使用して Azure Cloud Shell で Terraform を構成する
- Bash を使用して Windows で Terraform を構成する
- PowerShell を使用して Windows で Terraform を構成する

2. Terraform コードを実装する

サンプルの Terraform コードをテストして実行するディレクトリを作成し、それを現在のディレクトリにします。

providers.tf という名前のファイルを作成し、次のコードを挿入します。

terraform {
  required_version = ">=1.0"

  required_providers {
    azurerm = {
      source  = "hashicorp/azurerm"
      version = "~>3.0"
    }
    random = {
      source  = "hashicorp/random"
      version = ">= 3.4.0"
    }
  }
}

provider "azurerm" {
  features {}
}

main.tfという名前のファイルを作成し、次のコードを挿入して、データベースを実行する PostgreSQL フレキシブルサーバーをデプロイします。

resource "random_pet" "name_prefix" {
  prefix = var.name_prefix
  length = 1
}

resource "azurerm_resource_group" "default" {
  name     = random_pet.name_prefix.id
  ___location = var.___location
}

resource "azurerm_virtual_network" "default" {
  name                = "${random_pet.name_prefix.id}-vnet"
  ___location            = azurerm_resource_group.default.___location
  resource_group_name = azurerm_resource_group.default.name
  address_space       = ["10.0.0.0/16"]
}

resource "azurerm_network_security_group" "default" {
  name                = "${random_pet.name_prefix.id}-nsg"
  ___location            = azurerm_resource_group.default.___location
  resource_group_name = azurerm_resource_group.default.name

  security_rule {
    name                       = "test123"
    priority                   = 100
    direction                  = "Inbound"
    access                     = "Allow"
    protocol                   = "Tcp"
    source_port_range          = "*"
    destination_port_range     = "*"
    source_address_prefix      = "*"
    destination_address_prefix = "*"
  }
}

resource "azurerm_subnet" "default" {
  name                 = "${random_pet.name_prefix.id}-subnet"
  virtual_network_name = azurerm_virtual_network.default.name
  resource_group_name  = azurerm_resource_group.default.name
  address_prefixes     = ["10.0.2.0/24"]
  service_endpoints    = ["Microsoft.Storage"]

  delegation {
    name = "fs"

    service_delegation {
      name = "Microsoft.DBforPostgreSQL/flexibleServers"

      actions = [
        "Microsoft.Network/virtualNetworks/subnets/join/action",
      ]
    }
  }
}

resource "azurerm_subnet_network_security_group_association" "default" {
  subnet_id                 = azurerm_subnet.default.id
  network_security_group_id = azurerm_network_security_group.default.id
}

resource "azurerm_private_dns_zone" "default" {
  name                = "${random_pet.name_prefix.id}-pdz.postgres.database.azure.com"
  resource_group_name = azurerm_resource_group.default.name

  depends_on = [azurerm_subnet_network_security_group_association.default]
}

resource "azurerm_private_dns_zone_virtual_network_link" "default" {
  name                  = "${random_pet.name_prefix.id}-pdzvnetlink.com"
  private_dns_zone_name = azurerm_private_dns_zone.default.name
  virtual_network_id    = azurerm_virtual_network.default.id
  resource_group_name   = azurerm_resource_group.default.name
}

resource "random_password" "pass" {
  length = 20
}

resource "azurerm_postgresql_flexible_server" "default" {
  name                   = "${random_pet.name_prefix.id}-server"
  resource_group_name    = azurerm_resource_group.default.name
  ___location               = azurerm_resource_group.default.___location
  version                = "13"
  delegated_subnet_id    = azurerm_subnet.default.id
  private_dns_zone_id    = azurerm_private_dns_zone.default.id
  administrator_login    = "adminTerraform"
  administrator_password = random_password.pass.result
  zone                   = "1"
  storage_mb             = 32768
  sku_name               = "GP_Standard_D2s_v3"
  backup_retention_days  = 7

  depends_on = [azurerm_private_dns_zone_virtual_network_link.default]
}

postgresql-fs-db.tfという名前のファイルを作成し、次のコードを挿入してデータベースをインスタンス化します。

resource "azurerm_postgresql_flexible_server_database" "default" {
  name      = "${random_pet.name_prefix.id}-db"
  server_id = azurerm_postgresql_flexible_server.default.id
  collation = "en_US.utf8"
  charset   = "UTF8"
}

variables.tf という名前のファイルを作成し、次のコードを挿入します。

variable "name_prefix" {
  default     = "postgresqlfs"
  description = "Prefix of the resource name."
}

variable "___location" {
  default     = "eastus"
  description = "Location of the resource."
}

outputs.tfという名前のファイルを作成し、次のコードを挿入して、リソースグループ名、Azure PostgreSQL サーバー名、および Azure PostgreSQL データベース名を出力します。

output "resource_group_name" {
  value = azurerm_resource_group.default.name
}

output "azurerm_postgresql_flexible_server" {
  value = azurerm_postgresql_flexible_server.default.name
}

output "postgresql_flexible_server_database_name" {
  value = azurerm_postgresql_flexible_server_database.default.name
}

output "postgresql_flexible_server_admin_password" {
  sensitive = true
  value     = azurerm_postgresql_flexible_server.default.administrator_password
}

3. Terraform を初期化する

terraform init 実行して、Terraform デプロイを初期化します。このコマンドは、Azureリソースを管理するために必要なAzureプロバイダーをダウンロードします。

terraform init -upgrade

重要なポイント:

-upgrade パラメーターは、必要なプロバイダープラグインを、構成のバージョン制約に準拠する最新バージョンにアップグレードします。

4. Terraform 実行プランを作成する

terraform プランを実行して実行プランを作成します。

terraform plan -out main.tfplan

重要なポイント:

terraform plan コマンドは実行プランを作成しますが、実行はしません。代わりに、それは設定ファイルで指定された設定を作成するために必要な手順を決定します。このパターンを使用すると、実際のリソースに変更を加える前に、実行プランが期待と一致するかどうかを確認できます。
任意の-outパラメーターを使用すると、プランの出力ファイルを指定することができます。 -out パラメーターを使用すると、レビューしたプランがそのまま適用されることが保証されます。

5. Terraform 実行プランを適用する

terraform apply を実行して、実行プランをクラウドインフラストラクチャに適用します。

terraform apply main.tfplan

重要なポイント:

terraform apply コマンドの例では、以前に terraform plan -out main.tfplanを実行していることを前提としています。
-out パラメーターに別のファイル名を指定した場合は、terraform apply への呼び出しで同じファイル名を使用してください。
-out パラメーターを使用しなかった場合は、パラメーターを指定せずに terraform apply を呼び出します。

az postgres flexible-server db show を実行して、Azure PostgreSQL データベースを表示します。

az postgres flexible-server db show --resource-group <resource_group_name> --server-name <server_name> --database-name <database_name>

重要なポイント:

<resource_group_name>、<server_name>、および <database_name> の値が terraform apply 出力に表示されます。

Get-AzPostgreSqlFlexibleServerDatabase を実行して、Azure PostgreSQL データベースを表示します。

Get-AzPostgreSqlFlexibleServerDatabase -ResourceGroupName <resource_group_name> -ServerName <server_name> -Name <database_name>

重要なポイント:

<resource_group_name>、<server_name>、および <database_name> の値が terraform apply 出力に表示されます。

7.リソースをクリーンアップする

Terraform を使用して作成されたリソースが不要になったら、次の手順を実行します。

terraform プランを実行し、destroy フラグを指定します。
```
terraform plan -destroy -out main.destroy.tfplan
```
重要なポイント:
- terraform plan コマンドは実行プランを作成しますが、実行はしません。代わりに、それは設定ファイルで指定された設定を作成するために必要な手順を決定します。このパターンを使用すると、実際のリソースに変更を加える前に、実行プランが期待と一致するかどうかを確認できます。
- 任意の-outパラメーターを使用すると、プランの出力ファイルを指定することができます。 -out パラメーターを使用すると、レビューしたプランがそのまま適用されることが保証されます。
terraform apply を実行して実行プランを適用します。
```
terraform apply main.destroy.tfplan
```

Azure での Terraform のトラブルシューティング

Azure で Terraform を使用するときの一般的な問題のトラブルシューティング

次のステップ

PostgreSQL フレキシブルサーバーの詳細

次の方法で共有

Terraform を使用して PostgreSQL フレキシブル サーバー データベースをデプロイする

1. 環境を構成する

2. Terraform コードを実装する

3. Terraform を初期化する

4. Terraform 実行プランを作成する

5. Terraform 実行プランを適用する

6. 結果を確認する

7.リソースをクリーンアップする

Azure での Terraform のトラブルシューティング

次のステップ

フィードバック

その他のリソース

Terraform を使用して PostgreSQL フレキシブルサーバーデータベースをデプロイする