これらのクエリを Azure ポータルで使用する方法については、Log Analytics のチュートリアルをご覧ください。 For the REST API, see Query.
時間経過における平均往復時間
すべての接続における往復時間（ミリ秒単位）を、10分間隔で10パーセンタイル、50パーセンタイル、90パーセンタイルでグラフ表示する。
WVDConnectionNetworkData
| summarize percentiles(EstRoundTripTimeInMs, 90, 50, 10) by bin(TimeGenerated,10m)
| render timechart
すべての接続における平均帯域幅
10 パーセンタイル、50 パーセンタイル、90 パーセンタイルで 10 分間隔にわたるすべての接続の帯域幅 (KB/秒) のグラフを表示します。
WVDConnectionNetworkData
| summarize percentiles(EstAvailableBandwidthKBps, 90, 50, 10) by bin(TimeGenerated,10m)
| render timechart
ラウンドトリップ時間が最も長いトップ10ユーザー
平均往復時間（ミリ秒単位）が最も高い上位10人のユーザーのリストを返します。
WVDConnectionNetworkData
| join kind=leftouter
(
WVDConnections
| where State == "Completed"
| distinct CorrelationId, UserName
) on CorrelationId
| summarize AvgRTT=round(avg(EstRoundTripTimeInMs)), RTT_P95=percentile(EstRoundTripTimeInMs, 95) by UserName
| top 10 by AvgRTT desc
帯域幅が最も低いユーザー上位10人
平均帯域幅が最も低い上位10人のユーザーのリストを返します（秒あたりキロバイト単位）。
WVDConnectionNetworkData
| join kind=inner
(
WVDConnections
| where State == "Completed"
| distinct CorrelationId, UserName
) on CorrelationId
| summarize AvgBW=avg(EstAvailableBandwidthKBps), BW_P95=percentile(EstAvailableBandwidthKBps,95) by UserName
| top 10 by AvgBW asc
ラウンドトリップ時間と帯域幅の概要
各接続のラウンドトリップ時間 (ミリ秒単位) と帯域幅 (キロバイト単位) の 90 パーセンタイルと、追加の接続の詳細を返します。
WVDConnectionNetworkData
| summarize RTTP90=percentile(EstRoundTripTimeInMs,90), BWP90=percentile(EstAvailableBandwidthKBps,90), StartTime=min(TimeGenerated), EndTime=max(TimeGenerated) by CorrelationId
| join kind=inner
(
WVDConnections
| where State == "Connected"
| extend Protocol = iif(UdpUse in ("0", "<>"), "TCP", "UDP")
) on CorrelationId
| project CorrelationId, StartTime, EndTime, UserName, SessionHostName, RTTP90, BWP90, Protocol, ClientOS, ClientType, ClientVersion, ConnectionType, ResourceAlias, SessionHostSxSStackVersion