Consultas para la tabla ACSSMSIncomingOperations

Para obtener información sobre el uso de estas consultas en Azure Portal, consulte Tutorial de Log Analytics. Para la API de REST, consulte Consulta.

Lista de operaciones SMS distintas

Devuelve todas las combinaciones distintas de pares de versiones y operación de SMS.

ACSSMSIncomingOperations
| distinct OperationName, OperationVersion 
| limit 100

Cálculo de percentiles de duración de las operaciones de SMS

Calcula los percentiles 90, 95 y 99 de la duración de la ejecución en milisegundos para cada operación de SMS. Se puede personalizar para ejecutarse para una sola operación o para otros percentiles.

ACSSMSIncomingOperations
// where OperationName == "<operation>" // This can be uncommented and specified to calculate only a single operation's duration percentiles
| summarize percentiles(DurationMs, 90, 95, 99) by OperationName, OperationVersion // calculate 90th, 95th, and 99th percentiles of each Operation
| limit 100

5 direcciones IP principales por operación de SMS

Para cada operación de SMS, capture las 5 direcciones IP que más han llamado a esa operación.

ACSSMSIncomingOperations
// | where OperationName == "<operation>" // This can be uncommented and specified to calculate only a single operation's count
| top-nested of OperationName by dummy=max(0), // For all the Operations...
  top-nested 5 of CallerIpAddress by count() // List the IP address that have called that operation the most
| project-away dummy // Remove dummy line from the result set
| limit 100

Errores operativos de SMS

Enumera todos los errores de SMS ordenados por antigüedad.

ACSSMSIncomingOperations
| where ResultType == "Failed"
| project TimeGenerated, OperationName, OperationVersion, ResultSignature, ResultDescription
| order by TimeGenerated desc
| limit 100

Recuento de resultados de la operación de SMS

Para cada operación de SMS, cuenta los tipos de resultados devueltos.

ACSSMSIncomingOperations
| summarize Count = count() by OperationName, ResultType //, ResultSignature // This can also be uncommented to determine the count of each ResultSignature for each ResultType 
| order by OperationName asc, Count desc
| limit 100