Consultas para la tabla ACSChatIncomingOperations

Para obtener información sobre el uso de estas consultas en Azure Portal, consulte tutorial de Log Analytics. Para obtener la API REST, consulte Consulta.

Operaciones de chat

Devuelve todas las combinaciones distintas de pares de operación de chat y versiones.

ACSChatIncomingOperations
| distinct OperationName, OperationVersion 
| limit 100

Calcular percentiles de duración de la actividad de chat

Calcula los percentiles 90, 95 y 99 de duración de ejecución en milisegundos para cada operación de chat. Se puede personalizar para ejecutarse para una sola operación o para otros percentiles.

ACSChatIncomingOperations
// where OperationName == "<operation>" // This can be uncommented and specified to calculate only a single operation's duration percentiles
| summarize percentiles(DurationMs, 90, 95, 99) by OperationName, OperationVersion // calculate 90th, 95th, and 99th percentiles of each Operation
| limit 100

5 direcciones IP principales por operación de chat

Para cada operación de chat, obtenga las 5 direcciones IP que más han utilizado esa operación.

ACSChatIncomingOperations
// | where OperationName == "<operation>" // This can be uncommented and specified to calculate only a single operation's count
| top-nested of OperationName by dummy=max(0), // For all the Operations...
  top-nested 5 of CallerIpAddress by count() // List the IP address that have called that operation the most
| project-away dummy // Remove dummy line from the result set
| limit 100

Errores operativos de chat

Enumera todos los errores de chat por orden de reciente.

ACSChatIncomingOperations
| where ResultType == "Failed"
| project TimeGenerated, OperationName, OperationVersion, ResultSignature, ResultDescription
| order by TimeGenerated desc
| limit 100

Recuentos de resultados de la operación de chat

Para cada operación de chat, cuente los tipos de resultados devueltos.

ACSChatIncomingOperations
| summarize Count = count() by OperationName, ResultType //, ResultSignature // This can also be uncommented to determine the count of each ResultSignature for each ResultType 
| order by OperationName asc, Count desc
| limit 100