Consultas para la tabla ACSCallAutomationIncomingOperations

Para obtener información sobre el uso de estas consultas en Azure Portal, consulte tutorial de Log Analytics. Para obtener la API REST, consulte Consulta.

Operaciones de Automatización de llamadas

Devuelve todas las combinaciones distintas de pares de versiones y operación de automatización de llamadas.

ACSCallAutomationIncomingOperations
| distinct OperationName, OperationVersion 
| limit 100

Calcular los percentiles de duración de las operaciones de automatización de llamadas

Calcula los percentiles 90, 95 y 99 de duración de ejecución en milisegundos para cada operación de automatización de llamadas. Se puede personalizar para ejecutarse para una sola operación o para otros percentiles.

ACSCallAutomationIncomingOperations
// where OperationName == "<operation>" // This can be uncommented and specified to calculate only a single operation's duration percentiles
| summarize percentiles(DurationMs, 90, 95, 99) by OperationName, OperationVersion // calculate 90th, 95th, and 99th percentiles of each Operation
| limit 100

5 direcciones IP principales por operación de automatización de llamadas

Para cada operación de automatización de llamadas, capture las 5 direcciones IP que más han llamado a esa operación.

ACSCallAutomationIncomingOperations
// | where OperationName == "<operation>" // This can be uncommented and specified to calculate only a single operation's count
| top-nested of OperationName by dummy=max(0), // For all the Operations...
  top-nested 5 of CallerIpAddress by count() // List the IP address that have called that operation the most
| project-away dummy // Remove dummy line from the result set
| limit 100

Errores operativos en la automatización de llamadas

Enumera todos los errores de automatización de llamadas ordenados por orden de más reciente a más antiguo.

ACSCallAutomationIncomingOperations
| where ResultType == "Failed"
| project TimeGenerated, OperationName, OperationVersion, ResultSignature
| order by TimeGenerated desc
| limit 100

Recuentos de resultados de la operación de Automatización de llamadas

Para cada operación de automatización de llamadas, cuente los tipos de resultados devueltos.

ACSCallAutomationIncomingOperations
| summarize Count = count() by OperationName, ResultType //, ResultSignature // This can also be uncommented to determine the count of each ResultSignature for each ResultType 
| order by OperationName asc, Count desc
| limit 100

Registros de automatización de llamadas para el identificador de conexión de llamadas

Consulta los registros de automatización de llamadas para un ID de conexión de llamada determinado.

ACSCallAutomationIncomingOperations
//| where CallConnectionId == "<callConnectionId>" // This can be uncommented to filter on a specific call connection ID
| limit 100

Llamada a operaciones de API de Automation en una llamada

Devuelve todos los pares de operación y versión de la API de Automatización de Llamadas para una llamada específica (ID de correlación).

ACSCallAutomationIncomingOperations
//| where CorrelationId == "<correlation ID>" // This can be uncommented to filter on a specific correlation ID
| project CorrelationId, OperationName, OperationVersion
| limit 100

Registro de CallDiagnostics para la llamada API CallAutomation

Consulta el registro de diagnóstico para una llamada con la que la API de Automatización de llamadas interactúó mediante el identificador de correlación.

ACSCallAutomationIncomingOperations 
//| where CorrelationId == "<correlation ID>" // This can be uncommented to filter on a specific correlation ID
| join kind=inner
    (ACSCallDiagnostics)
    on CorrelationId
| limit 100

Registro CallSummary para la llamada API CallAutomation

Consulta el registro de resumen de una llamada con la que la API de Automatización de llamadas interactúó mediante el identificador de correlación.

ACSCallAutomationIncomingOperations 
//| where CorrelationId == "<correlation ID>" // This can be uncommented to filter on a specific correlation ID
| join kind=inner
    (ACSCallSummary)
    on CorrelationId
| limit 100

Número de llamadas con MediaStreaming activo

Calcula el número de llamadas que tenían MediaStreaming activo.

ACSCallAutomationStreamingUsage 
    | where StreamingModality contains "AudioStreaming" 
    | summarize NumCallsWithMediaStreamingActive = dcount(CallConnectionId) 

Conteo de éxitos de operaciones de MediaStreaming

Calcula el número de éxito de la operación MediaStreaming.

ACSCallAutomationIncomingOperations
// Filter OperationName to view results for each API. 
    | where OperationName in ("StartMediaStreaming", "StopMediaStreaming")
    | where tostring(ResultSignature) matches regex "2.."
    | summarize MediaStreamingSuccess=count() by ResultSignature

Recuento de errores de la operación MediaStreaming

Calcula el número de errores de la operación MediaStreaming.

ACSCallAutomationIncomingOperations 
// Filter OperationName to view results for each API.
    | where OperationName in ("StartMediaStreaming", "StopMediaStreaming")
    | where tostring(ResultSignature) matches regex "5.."
    | summarize MediaStreamingFailures=count() by ResultSignature

Número de llamadas con transcripción activa

Calcula el número de llamadas que tenían la transcripción activa.

ACSCallAutomationStreamingUsage 
    | where StreamingModality == "Transcription" 
    | summarize NumCallsWithTranscriptionActive = dcount(CallConnectionId)

Recuento de éxitos de la operación de transcripción

Calcula el número de éxito de la operación de transcripción.

ACSCallAutomationIncomingOperations
// Filter OperationName to view results for each API.
    | where OperationName in ("StartTranscription", "StopTranscription", "UpdateTranscription")
    | where tostring(ResultSignature) matches regex "2.."
    | summarize TranscriptionSuccess=count()

Recuento de errores de la operación de transcripción

Calcula el número de errores de la operación de transcripción.

ACSCallAutomationIncomingOperations 
// Filter OperationName to view results for each API.
    | where OperationName in ("StartTranscription", "StopTranscription", "UpdateTranscription")
    | where tostring(ResultSignature) matches regex "5.."
    | summarize TranscriptionFailures=count()